@echo off
setlocal

REM === Umgebungsvariablen setzen ===
set JAVA_HOME=C:\oracle\Java\jdk-1.8
set MW_HOME=C:\oracle\Middleware\Oracle_Home
set DOMAIN_HOME=%MW_HOME%\user_projects\domains\base_domain
set PATH=%JAVA_HOME%\bin;%JAVA_HOME%\jre\bin;%MW_HOME%\oracle_common\common\bin;%PATH%

REM === Log-Verzeichnis sicherstellen ===
set LOG_DIR=C:\oracle\Middleware\fr_config
if not exist "%LOG_DIR%" mkdir "%LOG_DIR%"

REM === Arbeitsverzeichnis setzen ===
cd /d "%DOMAIN_HOME%\bin"

echo [%date% %time%] Starte WebLogic AdminServer >> "%LOG_DIR%\startWeblogic.log"
start "" "%DOMAIN_HOME%\bin\startWebLogic.cmd"

REM Warte, bis AdminServer hochkommt
timeout /t 20 /nobreak

echo [%date% %time%] Starte NodeManager >> "%LOG_DIR%\startNodeManager.log"
start "" "%DOMAIN_HOME%\bin\startNodeManager.cmd"

REM Warte, bis NodeManager bereit ist
timeout /t 20 /nobreak

echo [%date% %time%] Starte Managed Server WLS_FORMS >> "%LOG_DIR%\startManagedWebLogicForms.log"
start "" "%DOMAIN_HOME%\bin\startManagedWebLogic.cmd" WLS_FORMS t3://localhost:7001

timeout /t 20 /nobreak

echo [%date% %time%] Starte Managed Server WLS_REPORTS >> "%LOG_DIR%\startManagedWebLogicReports.log"
start "" "%DOMAIN_HOME%\bin\startManagedWebLogic.cmd" WLS_REPORTS t3://localhost:7001

REM Warte länger, bevor WLST ausgeführt wird
timeout /t 40 /nobreak

echo [%date% %time%] Prüfe ReportsServer Instanzen via WLST >> "%LOG_DIR%\startManagedWebLogicReportsServer2.log"
"C:\oracle\Middleware\Oracle_Home\oracle_common\common\bin\wlst.cmd" "C:\oracle\Middleware\fr_config\manageReportsServer.py"

endlocal